home *** CD-ROM | disk | FTP | other *** search
/ ShareWare OnLine 2 / ShareWare OnLine Volume 2 (CMS Software)(1993).iso / util2 / sutl.zip / SAMPLE.BAS next >
BASIC Source File  |  1993-03-01  |  2KB  |  66 lines
  1. 100 ' SAMPLE.BAS -- by PS
  2. 110 ' (c) 1988 Ziff Communications Co.
  3. 120 '
  4. 130 PRINT "This creates four screens, in 40-"
  5. 140 PRINT "and 80-column text modes, and in"
  6. 150 PRINT "320x200 and 640x200 graphics modes."
  7. 160 PRINT "Each will pause when it's done."
  8. 170 PRINT "Press any key at that point to"
  9. 180 PRINT "continue.  Use these sample images"
  10. 190 PRINT "with CAMERA.COM and CAMLOAD.BAS"
  11. 200 PRINT "(Now press any key to start)"
  12. 210 WHILE INKEY$="":WEND
  13. 220 '
  14. 230 ' -- 40TEXT --
  15. 240 '
  16. 250 KEY OFF:SCREEN 0:WIDTH 40:K=1
  17. 260 COLOR 1,0,0:CLS:LOCATE ,,0
  18. 270 S$=CHR$(206)
  19. 280 A$(1)=CHR$(201)+S$+S$+CHR$(187)
  20. 290 A$(2)=S$+CHR$(188)+CHR$(200)+S$
  21. 300 A$(3)=S$+CHR$(187)+CHR$(201)+S$
  22. 310 A$(4)=CHR$(200)+S$+S$+CHR$(188)
  23. 320 FOR A=1 TO 21 STEP 4
  24. 330 FOR B=1 TO 36 STEP 4
  25. 340 FOR C=1 TO 4
  26. 350 LOCATE C+A-1,B+2:PRINT A$(C);
  27. 360 NEXT:COLOR K MOD 6+1:K=K+1
  28. 370 NEXT:NEXT:LOCATE 1
  29. 380 WHILE INKEY$="":WEND
  30. 390 '
  31. 400 ' -- 80TEXT --
  32. 410 '
  33. 420 WIDTH 80:COLOR 1,0,0:CLS
  34. 430 A$=CHR$(176):B$=CHR$(177)
  35. 440 C$=CHR$(178):D$=CHR$(219)
  36. 450 FOR A=1 TO 23
  37. 460 COLOR A MOD 6+1,A MOD 5+2
  38. 470 FOR B=1 TO 10
  39. 480 PRINT A$+B$+C$+D$+C$+B$+A$+A$;
  40. 490 NEXT:NEXT:LOCATE 1
  41. 500 WHILE INKEY$="":WEND
  42. 510 '
  43. 520 ' -- MEDRES --
  44. 530 '
  45. 540 SCREEN 1:COLOR 1,0:CLS
  46. 550 FOR E=1 TO 75
  47. 560 A=RND*300+7:B=RND*130+12:C=RND*5+5
  48. 570 FOR F=1 TO C STEP 2
  49. 580 LINE (A,199)-(A,B)
  50. 590 CIRCLE (A,B),F,(F MOD 3)+1
  51. 600 CIRCLE (A+1,B-1),F,(F MOD 3)+1
  52. 610 NEXT:NEXT
  53. 620 WHILE INKEY$="":WEND
  54. 630 '
  55. 640 ' -- HIRES --
  56. 650 '
  57. 660 SCREEN 2:CLS
  58. 670 FOR A=200 TO 1 STEP -2
  59. 680 LINE (0,A)-(639,A):NEXT
  60. 690 FOR E=1 TO 150
  61. 700 A=RND*600+1:B=RND*180+1:C=RND*20+5
  62. 710 LINE (A,B)-(A+C,B+C),0,BF
  63. 720 LINE (A+4,B+1)-(A+C+4,B+C+1),,BF
  64. 730 NEXT
  65. 740 WHILE INKEY$="":WEND
  66.